**Problema 1.** Faça um algoritmo que, após receber os nomes, as médias e as frequências de 10 alunos, deve imprimir em tela o nome de cada aluno e a sua situação, definida como “aprovado” (média >= 5.0 e frequência >= 75%), “reprovado por falta” (frequência < 75%) ou “reprovado por média” (frequência >= 75%, mas média < 5.0).

**Dica 1A.** Se precisássemos fazer para somente um aluno, bastaríamos ter variáveis nome (tipo Texto), media (tipo Real) e frequência (tipo Real), mas precisamos disso para 10 alunos. Que tipo de dado pode nos ajudar?

**Dica 1B.** Precisaremos receber e armazenar os dados 10 vezes e depois processar e imprimir 10 vezes. Que comando pode nos ajudar a executar tais instruções 10 vezes?

**Solução.**

ALGORITMO “Situacao\_Aluno1”

VARIAVEIS

nomes : vetor [1..10] de texto

medias : vetor [1..10] de real

frequencias : vetor [1..10] de real

i : inteiro

situacao : texto

INICIO

PARA i 🡨 1 ATÉ 10 PASSO 1 FAÇA

ESCREVAL(“Informe nome do aluno numero “, i)

LEIA(nomes[i])

ESCREVAL(“Informe media do aluno numero “, i)

LEIA(medias[i])

ESCREVAL(“Informe frequencia do aluno numero “, i)

LEIA(frequencias[i])

FIM-PARA

PARA i 🡨 1 ATÉ 10 PASSO 1 FAÇA

SE ( (medias[i] >= 5.0) E (frequências[i] >= 0.75) ) ENTÃO

situacao 🡨 “aprovado”

SENÃO

SE (frequências[i] < 0.75) ENTÃO

situacao 🡨 “reprovado por falta”

SENÃO

situacao 🡨 “reprovado por media”

FIM-SE

FIM-SE

ESCREVAL(nomes[i], “-->”, situacao)

FIM-PARA

FIM-ALGORITMO

**Para pensar.** O que aconteceria se todo o algoritmo estivesse em um único PARA, em vez de dois? E por que, para a situação “reprovado por media” não é preciso incluir um novo “SE”?

**Problema 2.** Faça um algoritmo que, após receber os nomes, as médias e as frequências de um número qualquer de alunos (mínimo de 1, máximo de 20), deve imprimir em tela o nome de cada aluno e a sua situação, definida como “aprovado” (média >= 5.0 e frequência >= 75%), “reprovado por falta” (frequência < 75%) ou “reprovado por média” (frequência >= 75%, mas média < 5.0).

**Dica 2A.** Desta vez, não sabemos exatamente quantos alunos serão informados, mas sabemos que são, no máximo, 20 alunos, e que pelo menos um aluno será informado. Que comando pode nos ajudar quando precisamos repetir certas instruções e não sabemos exatamente quantas vezes?

**Solução.**

ALGORITMO “Situacao\_Aluno2”

VARIAVEIS

nomes : vetor [1..20] de texto

medias : vetor [1..20] de real

frequencias : vetor [1..20] de real

opcao : caracter

i, total : inteiro

situacao : texto

INICIO

total 🡨 0

REPITA

total 🡨 total + 1

ESCREVAL(“Informe nome do aluno numero “, total)

LEIA(nomes[total])

ESCREVAL(“Informe media do aluno numero “, total)

LEIA(medias[total])

ESCREVAL(“Informe frequencia do aluno numero “, total)

LEIA(frequencias[total])

ESCREVAL(“Há mais alunos a serem cadastrados?”)

LEIA(opcao)

ATE-QUE (opcao = “N”)

PARA i 🡨 1 ATÉ total PASSO 1 FAÇA

SE ( (medias[i] >= 5.0) E (frequências[i] >= 0.75) ) ENTÃO

situacao 🡨 “aprovado”

SENÃO

SE (frequências[i] < 0.75) ENTÃO

situacao 🡨 “reprovado por falta”

SENÃO

situacao 🡨 “reprovado por media”

FIM-SE

FIM-SE

ESCREVAL(nomes[i], “-->”, situacao)

FIM-PARA

FIM-ALGORITMO

**Para pensar.** Por que não é possível resolver esse problema sem uma variável total? E por que o comando PARA não pode ir de 1 até 20?

**Problema 3.** A sequência de Fibonacci é uma série de números bastante conhecida e empregada na matemática, que começa com seus dois primeiros valores sendo iguais a 1 e, a partir do terceiro, o novo valor é sempre calculado a partir da soma dos dois anteriores. Assim, a sequência 1-1-2-3-5-8-13-21 é uma sequência de Fibonacci de 8 números. Faça um algoritmo que, dado um número N informado pelo usuário, calcule e imprima os N primeiros números da sequência de Fibonacci.

**Dica 3A.** Os únicos dois valores “fixos” são 1 e 1 (os dois primeiros números da sequência). Se quisermos imprimir mais valores da sequência, precisamos manter os dois últimos valores em duas variáveis (A e B, por exemplo) para então calcular o novo valor (o valor de C, por exemplo). Além disso, é interessante observar que estamos mais uma vez lidando com um intervalo de valores bem definido: de 1 até N!

**Solução.**

ALGORITMO “Fibonacci”

VARIAVEIS

A, B, C, I, N : inteiro

INICIO

A 🡨 1

B 🡨 1

C 🡨 0

ESCREVAL(“Qual o tamanho da sequencia desejado?”)

LEIA(N)

SE (N > 0) ENTÃO

ESCREVA(“1”)

FIM-SE

SE (N > 1) ENTÃO

ESCREVA(“-1”)

FIM-SE

SE (N > 2) ENTÃO

PARA i 🡨 3 ATÉ N PASSO 1 FAÇA

C 🡨 A + B

ESCREVA(“-“, C)

A 🡨 B

B 🡨 C

FIM-PARA

FIM-SE

FIM-ALGORITMO

**Para pensar.** Em nosso algoritmo, qual é o papel das variáveis A, B e C? O que elas armazenam? Por que, dentro do laço, eu preciso armazenar o valor de B em A e o valor de C em B? O que aconteceria se eu fizesse isso fora do laço, após ele? E se eu primeiro atribuísse o valor de C a B e só depois atribuísse B a A?